DISKUSE
Tělo zprávy, jako MIME, se nezobrazí v RTX poli Bo... 
01.11.2019 12:14

Sametime (4)
25.10.2019 10:14

Zprávy v LotusScriptu 
11.09.2019 20:33

export vložených příloh z dokumentové knihovny 
05.08.2019 12:50

Kalkulačka  (1)
30.07.2019 13:19

Problém s polem From v mailech posílaných přes SMT... 
01.07.2019 16:30

ECL 
03.04.2019 16:10

Agent přestal fungovat (1)
18.03.2019 08:28


ŠKOLENÍ


REKLAMA


KOMENTÁŘE

Přeposílání výtahu z důležitých mailů jako SMS zprávy

Vytisknout článek

Mail je dobrá věc, horší je když člověk je na cestách a má s sebou jen mobil (zatím ještě bez integrovaného POP3 mailu a webového prohlížeče). Jedním z řešení je přeposílání výtahů z "důležitých" mailů ve formě SMS zpráv.


Mail je dobrá věc, horší je když člověk je na cestách a má s sebou jen mobil (zatím ještě bez integrovaného POP3 mailu a webového prohlížeče). Jedním z řešení je přeposílání výtahů z "důležitých" mailů ve formě SMS zpráv.

Jak ale určit důležitý mail ? U větších firem se již zavedlo použití příznaku "důležitá zpráva" - takže proč jej nevyužít ? A pak už jen stačí zajistit technickou stránku věci, tj. vlastní přeposlání mailu.

Realizace je jednoduchá: stačí do své mailové databáze napsat privátní agent, spouštěný příchodem nového mailu, který zkontroluje, zda mail má nastavený příznak vysoké důležitosti nebo vysoké priority a pokud ano, vygeneruje nový mail, který odešle na adresu SMS brány a v jehož tělu je prvních např. 150 znaků z původního mailu.

Za tímto účelem je např. u Paegasu vhodné zřídit si na webových stránkách Paegasu mailovou adresu ve stylu mojeadresa@sms.paegas.cz, protože doručování na adresy stylu 420603xxxxxx@sms.paegas.cz občas chodí, občas ne. Obdobné řešení zřejmě bude i u Eurotelu a Oscara.

Jen upozornění: příchozí pošta nesmí u konkrétního uživatele být kryptována (v nastavení NAB uživatele), jinak se na ni samozřejmě agentem nedostanete.

Option Public
Option Declare

Sub Initialize
Dim session As New NotesSession
Dim dbCurrent As NotesDatabase
Dim collUnprocessed As NotesDocumentCollection
Dim docCurrent As NotesDocument
Dim itemBody As NotesItem
Dim strPriority As String, strImportance As String
Dim varBody As Variant
Dim strSendTo(1) As String
strSendTo(0) = "mojeadresa@sms.pagegas.cz"
strSendTo(1) = "pripadna.dalsi.adresa@sms.pagegas.cz"

Set dbCurrent = session.CurrentDatabase
If (dbCurrent Is Nothing) Then
Print "dbCurrent neni nastavena"
Else
Set collUnprocessed = dbCurrent.UnprocessedDocuments
If collUnprocessed.Count < 1 Then
Print "Zadne dokumenty ke zpracovani"
Else
Set docCurrent = collUnprocessed.GetFirstDocument
If (docCurrent Is Nothing) Then
Print "Nelze ziskat handle na dokument"
Else
Do
strPriority = docCurrent.DeliveryPriority(0)
strImportance = docCurrent.Importance(0)
If ((docCurrent.Form(0) = "Memo") And (strPriority = "H" Or strImportance = "1")) Then
'Vytvorime novy dokument a mailneme jej
Dim docPagerMemo As New NotesDocument(dbCurrent)
Dim varFrom As Variant, strSubject As String, strBodyText As String
docPagerMemo.SendTo = strSendTo
varFrom = Evaluate({@Name([CN]; From)}, docCurrent)
strSubject = docCurrent.Subject(0)
Set itemBody = docCurrent.GetFirstItem("Body")
If (itemBody Is Nothing) Then
'Telo dokumentu nelze precist
Print "itemBody neni nastaven"
docPagerMemo.Body = "Text nelze precist. Zkontrolujte email. | Od: " & varFrom
Else
'Pokud lze precist Body, vezmeme prvnich 200 znaku
'break down variables for debugging
strBodyText = "From: " & varFrom(0) & " : " & strSubject & " - " & Left(itemBody.Text, 200)
docPagerMemo.Body = strBodyText
End If
Call docPagerMemo.Send(False)
Print "Odeslano"

Call session.UpdateProcessedDoc(docCurrent)
End If
Set docCurrent = collUnprocessed.GetNextDocument(docCurrent)
Loop Until (docCurrent Is Nothing)
End If
End If
End If
End Sub

Celé řešení převzaté z diskuzního fóra by šlo zefektivnit, dobré by bylo rovněž poskytnout jej všem uživatelům zabudováním přímo do template mailové databáze, zrušit "natvrdo" zabudované mailové adresy a umístit je do profilových dokumentů jednotlivých uživatelů nebo přímo do NAB, příp. zabudovat mechanismum rozpoznávání klíčových slov v textu a v hlavičce mailu (který by umožnil brát v potaz nejenom příznak důležitosti, ale i např. výskyt jména nebo mailové adresy konkrétní osoby, téma atd.). Nicméně - řešení "chodí" a iniciativě se meze nekladou.


Autor: Zdeněk Michálek
Datum: 05.04.2001


Sdílet článek Seznam komentářů

Zatím nebyl přidán žádný komentář. Buďte první!